Smart之温湿度采集与控制

1. 说明

  范例使用ModbusTCP通讯协议，读取连接至Arduino的温湿度传感器数据，同时可通过ModbusTCP来控制LED灯以及继电器开关。可通过视频直播流查看正在播放的设备运行情况。

  范例除使用常规的Arduino硬件外，还需要使用到用于进行直播录像的摄像机，该摄像机录制的视频将以视频直播流的形式发送至指定的RTMP服务器中，范例从该地址中接收视频流播放视频录像。在使用该范例前需要读者对视频直播的流程有一定的了解，并使用自行搭建的流媒体服务器或者第三方的视频直播服务进行推流直播。自行搭建的流媒体服务器可使用SRS (opens new window)。

  通过范例学习，可以掌握ModbusTCP的基本通讯原理，实现Arduino设备的综合控制。

2. 零件连接图

  零件连接如下图所示，其中电动机的部分为制冷与风扇的外围电路，制冷器与温湿度传感器紧贴。

3. 使用零件

序	零件名称	数量
1	Arduino UNO R3 开发板	1
2	W5100网络扩展板	1
3	USB数据线	1
4	面包板	1
5	杜邦线	若干
6	LED灯	1
7	220欧姆电阻	1
8	LCD1602液晶显示屏(I2C接口)	1
9	DHT11温湿度传感器	1
10	继电器	1
11	半导体制冷片	1
12	电动机	1

4. Arduino流程图

5. Arduino程序

  使用Arduino IDE 编译并上传以下Arduino程序。

// 使用温湿度传感器之链接库 https://github.com/adafruit/DHT-sensor-library
// 采用 MyArduinoProjects Modbus TCP 链接库 http://myarduinoprojects.com/modbus.html
// 读取温湿度 因为modbus 无法传递小数字  所以先乘100 到客户端取用时要除 100
 
#include <DHT.h>
#include <SPI.h>
#include <Ethernet.h>
#include <MgsModbus.h>    // 引入Modbus TCP 链接库
#include <LiquidCrystal_I2C.h> //引用I2C库
MgsModbus Mb;

//设置LCD1602设备地址，一般是0x20，或者0x27，具体看模块手册
LiquidCrystal_I2C lcd(0x27,16,2); 
 
#define dhtPin 8                    //读取DHT11 Data
#define dhtType DHT11               //选用DHT11 
DHT dht(dhtPin, dhtType); // Initialize DHT sensor

#define LED_PIN 9                   //定义LED PIN为 9
#define COOLER_PIN 7                //定义制冷器PIN为 7
 
// 设置网络IP地址 (网络扩充卡 MAC 可自行修改 +1 避免冲突)
byte mac[] = {0x90, 0xA2, 0xDA, 0x0E, 0x94, 0xB8 };     
IPAddress ip(192, 168, 0, 183);
IPAddress gateway(192, 168, 0, 1);
IPAddress subnet(255, 255, 255, 0);
 
void setup() {
   Serial.begin(9600);              //设定鲍率9600
   Ethernet.begin(mac, ip, gateway, subnet);               // 启动网络
   Serial.println("网络已经开通"); 
   pinMode(LED_PIN, OUTPUT); 
   pinMode(COOLER_PIN, OUTPUT);
   
   lcd.init();                  // 初始化LCD
   lcd.backlight();             //设置LCD背景等亮
   lcd.setCursor(0,0);                //设置显示指针
   lcd.print("IsoFace LiveDemo"); 
 
   //设置要使用的缓存器地址
   //0 1 2 3 4 是 Holding 缓存器的顺序,其地址分别是10000,10001,10002,10003,10004
   // 新增缓存器   mb.MbData(i);   
   Mb.MbData[0] = 0;                                       // 地址 0 存放所测得之温度  
   Mb.MbData[1] = 0;                                       // 地址 1 存放所测得之湿度           
   Mb.MbData[2] = 0;                                       // 地址 2 存放LED灯的状态
   Mb.MbData[3] = 0;                                       // 地址 3 存放制冷器的状态   
   dht.begin();//启动DHT
 }
 
void loop() {

  // LED灯状态指示                         
   if (Mb.MbData[2]!=0){
       digitalWrite(LED_PIN, HIGH);                      //PIN 9输出为HIGH,LED点亮
   }
   else {    
       digitalWrite(LED_PIN, LOW);                       //PIN 9输出为LOW,LED熄灭
   }

   // 制冷器状态指示
   if (Mb.MbData[3]!= 0){
       digitalWrite(COOLER_PIN, HIGH);
   }
   else{
       digitalWrite(COOLER_PIN, LOW);
   }


  
   float h = dht.readHumidity()*100;                      //读取湿度 因为modbus 无法传递小数字  所以先乘100 到客户端取用时要除 100
   float t = dht.readTemperature()*100;                   //读取摄氏温度
   if (isnan(h) || isnan(t)) {
      Serial.println("无法从DHT传感器读取！");
      return;
   }
   Mb.MbData[0] = t;                                       // 地址 0 存放所测得之温度  
   Mb.MbData[1] = h;                                       // 地址 1 存放所测得之湿度  

   //输出显示状态
   lcd.clear();
   lcd.setCursor(0, 0);
   if (Mb.MbData[2] != 0){
    lcd.print("LED:ON   ");
   }
   else{
    lcd.print("LED:OFF  ");
   }
   
   if (Mb.MbData[3] != 0){
     lcd.print("FAN:ON  "); 
   }
   else{
     lcd.print("FAN:OFF ");
   }
   
   lcd.setCursor(0, 1);
   lcd.print("T:" + String(t*0.01)+ "  " + "H:" + String(h*0.01));   
   delay(500);                                             //延时 0.5 秒
   Mb.MbsRun();                                            //呼叫 Modbus   
}

6. 设计明细

  开启Smart智慧控制平台，分别加入下插图之控件。或者通过点击菜单栏[文件]-[打开项目]选择项目打开该范例。

  ①：TModbusTCP组件，控件名称为ModbusTCP。

  ②：TTimer组件，控件名称为Timer1。

  ③：TFSPlayer组件，控件名称为FSPlayer1。

  ④：TPanel组件，控件名称为pnVideoPanel。

  ⑤：TiSevenSegmentAnalog组件，控件名称为LCDTem。

  ⑥：TiSevenSegmentAnalog组件，控件名称为LCDHum。

  ⑦：TSwitchButton组件，控件名称为sbLED。

  ⑧：TSwitchButton组件，控件名称为sbFan。

• Main窗体属性设置

  • Caption：主窗体标题，设置为温湿度采集与控制。
  • ClientHeight：窗体客户区高度=562。
  • ClientWidth：窗体客户区宽度=566。

• ①ModbusTCP属性设置

  • Host：设置其连接的客户端的IP地址。
  • AutoConnect：设置控件是否自动连接至客户端，此处设置为True。

• ②Timer属性设置

  • Interval：设置计时器触发的时间间隔，单位为毫秒(ms)，设置为2000。

• ③FSPlayer1属性设置

  • Saturation：设置视频色彩的饱和度，设置为10。
  • VideoPanel：设置视频显示在哪个控件上，设置为pnVideoPanel。

• ④pnVideoPanel属性设置

  • Caption：设置面板显示的标签内容，设置为视频播放区域。

• ⑤LCDTem属性设置

  使用鼠标右键点击该控件，在选项中选择[Edit]，其中的选项修改如图所示，设置完成后，点击[OK]按钮保存设置。

• ⑥LCDHum属性设置

  使用鼠标右键点击该控件，在选项中选择[Edit]，其中的选项修改如图所示，设置完成后，点击[OK]按钮保存设置。

• ⑦sbLED属性设置

  • SwitchOff：设置IsChecked=False时显示的图片。点击属性右侧的[...]按钮，打开文件上传界面，点击[Load...]从文件浏览器中选择对应的图片文件上传，返回该界面下，待显示出图片后点击[OK]加载图片。

  

  • SwitchOn：设置IsChecked=True时显示的图片。点击属性右侧的[...]按钮，打开文件上传界面，点击[Load...]从文件浏览器中选择对应的图片文件上传，返回该界面下，待显示出图片后点击[OK]加载图片。

  

  • Height：设置控件显示的高度，设置为68。
  • Width：设置控件显示的宽度，设置为68。

• ⑧sbFan属性设置

  • SwitchOff：设置IsChecked=False时显示的图片。点击属性右侧的[...]按钮，打开文件上传界面，点击[Load...]从文件浏览器中选择对应的图片文件上传，返回该界面下，待显示出图片后点击[OK]加载图片。

  

  • SwitchOn：设置IsChecked=True时显示的图片。点击属性右侧的[...]按钮，打开文件上传界面，点击[Load...]从文件浏览器中选择对应的图片文件上传，返回该界面下，待显示出图片后点击[OK]加载图片。

  

  • Height：设置控件显示的高度，设置为68。
  • Width：设置控件显示的宽度，设置为68。

7. 程序设计

7.1. 程序初始设置

  程序启动时，读取ModbusTCP设备的相关数据信息，加载视频直播地址，开始直播视频的播放。

constructor TMyHandler.Create(AOwner: TComponent);
var
  hum,tmp,LED,Fan: Word;
begin
  FThis :=TBaseForm(AOwner);
  FThis.FSPlayer1.Open('http://192.168.0.113:8080/live/001.flv',False);
  FThis.ModbusTCP.ReadHoldingRegister(1,tmp);
  FThis.ModbusTCP.ReadHoldingRegister(2,hum);
  FThis.ModbusTCP.ReadHoldingRegister(3,LED);
  FThis.ModbusTCP.ReadHoldingRegister(4,Fan);
  FThis.LCDTem.Value := tmp * 0.01;
  FThis.LCDHum.Value := hum * 0.01;
  if LED = 1 then
    FThis.sbLED.IsChecked := True
  else
    FThis.sbLED.IsChecked := False;
  if Fan = 1 then
    FThis.sbFan.IsChecked := True
  else
    FThis.sbFan.IsChecked := False;
end;

7.2. 事件设置

• ②Timer1-OnTimer事件

  计时器的定时触发时间，读取数据并显示

procedure TMyHandler.TimerTimer;
var
  hum,tmp,LED,Fan: Word;
begin
  FThis.ModbusTCP.ReadHoldingRegister(1,tmp);
  FThis.ModbusTCP.ReadHoldingRegister(2,hum);
  FThis.LCDTem.Value := tmp * 0.01;
  FThis.LCDHum.Value := hum * 0.01;
end;

• ⑦sbLED-OnSwitch事件

  点击以切换LED的开关状态。

procedure TMyHandler.sbLEDSwitch;
begin
  if FThis.sbLED.IsChecked then
    FThis.ModbusTCP.WriteRegister(3,1)
  else
    FThis.ModbusTCP.WriteRegister(3,0);
end;

• ⑧sbFan-OnSwitch事件

  点击以切换制冷器的开关状态。

procedure TMyHandler.sbFanSwitch;
begin
  if FThis.sbFan.IsChecked then
    FThis.ModbusTCP.WriteRegister(4,1)
  else
    FThis.ModbusTCP.WriteRegister(4,0);
end;

8. 运行结果

  使用鼠标点击工具栏运行（Run），测试运行结果。

  通过工具栏保存，将程序保存为 sdb 项目文件。

  程序运行后，显示Arduino的直播画面，其中包含了LCD显示屏，LED灯以及制冷器的散热风扇等的状态显示。

  点击LED灯或者散热器的开关按钮，对应的元件开启或关闭，可在直播画面中看到状态的显示。