爱招飞帮助手册
目录

MQTT读取温湿度

# PinToo之MQTT读取温湿度

# 1. 说明

  采用MQTT通讯协议，读取驳接在Arduino上的DHT22温湿度传感器的数据。MQTT是由IBM开发的通讯协议，为传感器提供一个轻量可靠的二进制通信设定，使得开发MQTT与物联网，机器之间的通信变得非常简单。

  TARS中也提供了MQTT服务，使用TARS中的该服务可以实现设备之间的相互连接。在范例中Arduino开发板与Ethernet W5100网络扩展板，组装方式与前述章节相同。温湿度传感器DHT22，负极接Ethernet W5100扩展板的GND针脚，正极接扩展板5V针脚，信号线接扩展板D8针脚。

  通过本范例学习，可以掌握fxMQTTClient控件的基本使用，并结合Arduino开发板通过MQTT进行温湿度采集。

# 2. 零件连接图

# 3. 使用零件

序 零件名称 数量
1 Arduino UNO R3 开发板 1
2 Arduino Ethernet W5100 网络扩展板 1
3 DHT22温湿度 模块 1
4 USB数据线 1
5 面包板 1
6 杜邦线 若干

# 4. Arduino流程图

# 5. Arduino程序

  使用Arduino IDE 编译并上传以下Arduino程序。

// pubsubclient MQTT 链接库网址  https://github.com/knolleary/pubsubclient
// 使用温湿度传感器之链接库 https://github.com/adafruit/DHT-sensor-library

#include <DHT.h>
#define dhtPin 8                    //读取DHT22 Data
#define dhtType DHT22               //选用DHT22 
DHT dht(dhtPin, dhtType);       // Initialize DHT sensor

#include <SPI.h>
#include <Ethernet.h>
// MQTT 宣告 ========================================================
#include <PubSubClient.h>
EthernetClient ethClient;
PubSubClient client(ethClient);


// 设置网络IP地址 (网络扩充卡 MAC 可自行修改 +1 避免冲突)
byte mac[] = {0x90, 0xA2, 0xDA, 0x0E, 0x94, 0xB9 };     
IPAddress ip(192, 168, 0, 165);
IPAddress gateway(192, 168, 0, 1);
IPAddress subnet(255, 255, 255, 0);

void setup() {
   Serial.begin(9600);                                   //设定通信速率9600
   dht.begin();                                           //启动DHT

   //设置 MQTT ========================================================
   client.setServer("192.168.0.176", 1883);                 // 连接 MQTT Broker
   client.setCallback(subscribeReceive);                            // 设置从 MQTT Broker读取主题之后,自动运行之副程序

   Ethernet.begin(mac, ip, gateway, subnet);               // 启动网络
   Serial.println("网络已经开通"); 

   delay(1500);
 }

void loop() {
   float h = dht.readHumidity();   //读取湿度
   float t = dht.readTemperature(); //读取摄氏温度
   if (isnan(h) || isnan(t)) {
      Serial.println(" 无法从DHT传感器读取！");
      return;
   }

  if (!client.connected()) {                              // 如果未联机 MQTT Broker 将重新联机
     reconnect();     
  }
   client.loop();
    
   // MQTT 开始运作发送主题 传送温湿度到 MQTT Broker
   char tmp[20];
   char hum[20];
   dtostrf(t,3,2,tmp);                 // 将Float 转换为 char[]
   dtostrf(h,3,2,hum);
   Serial.println(tmp); 
   Serial.println(hum);
   // MQTT 发送主题(温湿度) =================
   client.publish("TMP", tmp);
   client.publish("HUM", hum);   
   delay(5000);
}

void reconnect() {
  // 一直循环直到连上 MQTT Broker
  while (!client.connected()) {
    Serial.print("正在连接 MQTT Broker...");
    if (client.connect("arduinoClient")) {
      Serial.println("MQTT Broker 已经连接上");
      client.subscribe("#");
 
    } else {
      Serial.print("联机失败, rc=");
      Serial.print(client.state());
      Serial.println("五秒钟之后再联机");
      delay(5000);
    }
  }
}

void subscribeReceive(char* topic, byte* payload, unsigned int length)
{
  // Print the topic
  Serial.print("Topic: ");
  Serial.println(topic);

  // Print the message
  Serial.print("Message: ");
  for(int i = 0; i < length; i ++)
  {
    Serial.print(char(payload[i]));
  }

  // Print a newline
  Serial.println("");
}
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95

# 6. 设计明细

  开启PinToo设计器，分别加入下插图之控件。或者点击左上角的[打开模板Lib文件]选择模板文件来打开对应模板。

MQTT读取温湿度 UI布局

  ①：TfxWidgetLCDLabel组件，控件名称为fxWidgetLCDLabel1。

  ②：TfxWidgetLCDLabel组件，控件名称为fxWidgetLCDLabel2。

  ③：TfxMQTTClient组件，控件名称为fxMQTTClientDHT22。

  ④：TfxSwitch组件，控件名称为fxSwitchSub。

  ⑤：TfxSwitch组件，控件名称为fxSwitchLog。

  • fxRunFrame属性设置

    • Height：设置页面高度=800。
    • Width：设置页面宽度=400。

  • fxMemoLog属性设置

    • Height：设置控件高度=155。
    • Width：设置控件宽度=380。
    • Visible：设置控件是否可见=False。
    • Name：设置控件名称=fxMemoLog。

  • ①fxWidgetLCDLabel1属性设置

    • Height：设置控件高度=95。
    • Width：设置控件宽度=285。
    • Color：设置背景颜色=Black。

  • ②fxWidgetLCDLabel2属性设置

    • Height：设置控件高度=95。
    • Width：设置控件宽度=285。
    • Color：设置背景颜色=Black。

  • ③fxMQTTClientDHT22属性设置

    • BrokerHostName：设置MQTT服务端的地址，此处设置与Arduino中指定的一致，如192.168.0.176。
    • BrokerPort：设置MQTT服务端的端口，此处设置与Arduino中指定的一致，如1883。
    • Name：设置控件名称=fxMQTTClientDHT22。

  • ④fxSwitchSub属性设置

    • Name：设置控件名称=fxSwitchSub。

  • ⑤fxSwitchLog属性设置

    • Name：设置控件名称=fxSwitchLog。

# 7. 程序设计

  点击程序设计界面右下角的按钮，切换至单元选择界面，勾选需要使用的单元。该程序需要引用 TMSMQTTConnection 、 TMSMQTTClient 、TMSMQTTGlobal 单元。

# 7.1. 程序初始设置

  程序在启动时连接MQTT服务端，同时修正显示屏的样式。

Begin
  //连接MQTTBroker
  fxMQTTClientDHT22.Connect(false);
  fxWidgetLCDLabel1.Caption.FillOff.Color := NULL;
  fxWidgetLCDLabel2.Caption.FillOff.Color := NULL; 
  fxWidgetLCDLabel1.Caption.Format := '000.00';
  fxWidgetLCDLabel2.Caption.Format := '000.00';
End.
1
2
3
4
5
6
7
8

# 7.2. 事件设置

  • ③fxMQTTClientDHT22-OnConnectedStatusChanged事件

  当MQTT连接状态发生变化时，在日志栏显示状态变更信息。

Procedure fxMQTTClientDHT22OnConnectedStatusChanged(ASender: TObject; AConnected: Boolean; AStatus: TTMSMQTTConnectionStatus);
//返回连接状态
Begin
   if AConnected then
   begin
     fxMemoLog.Lines.Add('MQTT Broker 连接成功！');
   end
   else
     fxMemoLog.Lines.Add('MQTT Broker 连接超时！');
End;
1
2
3
4
5
6
7
8
9
10
  • ③fxMQTTClientDHT22-OnPublishReceivedUTF8事件

  当接收到订阅信息时，处理并显示。

Procedure fxMQTTClientDHT22OnPublishReceivedUTF8(ASender: TObject; APacketID: Word; ATopic: string; APayload: string);
//添加订阅信息
Begin
  if ATopic = 'HUM' Then
  begin
    fxWidgetLCDLabel2.Caption.Value := StrToFloat(APayload);
    fxMemoLog.Lines.Add('湿度：'+APayload+' %');   
  End
  else if ATopic = 'TMP' Then
  begin
    fxWidgetLCDLabel1.Caption.Value := StrToFloat(APayload);
    fxMemoLog.Lines.Add('温度：'+APayload+' ℃');    
  End;
End;
1
2
3
4
5
6
7
8
9
10
11
12
13
14
  • ④fxSwitchSub-OnSwitch事件

  订阅状态的开关发生变化时，进行订阅或者取消订阅的操作。

Procedure fxSwitchSubOnSwitch(Sender: TObject);
//点击以订阅/取消订阅温湿度信息
Begin
  if fxSwitchSub.IsChecked Then
  //订阅
  begin   
    fxMQTTClientDHT22.Subscribe('HUM',qosAtMostOnce); //订阅湿度 HUM 主题
    fxMQTTClientDHT22.Subscribe('TMP',qosAtMostOnce); //订阅温度 TMP 主题                     
  End
  else
  //取消订阅
  begin
    fxMQTTClientDHT22.UnSubscribe('HUM'); //取消订阅湿度 HUM 主题
    fxMQTTClientDHT22.UnSubscribe('TMP'); //取消订阅温度 TMP 主题        
  End;
End;
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
  • ⑤fxSwitchLog-OnSwitch事件

  日志开关发生变化时，显示或者隐藏日志栏。

Procedure fxSwitchLogOnSwitch(Sender: TObject);
//是否显示日志
Begin
  if fxSwitchLog.IsChecked Then
  //开启log界面
    fxMemoLog.Visible := True
  else
  //关闭Log界面
    fxMemoLog.Visible := False;  
End;
1
2
3
4
5
6
7
8
9
10

# 8. 运行结果

  使用鼠标在 PinToo 菜单，点击[保存至数据库]按钮，将其保存至数据库，点击[调试运行]确认能够正常打开。

MQTT读取温湿度 运行结果   通过同步中心，将程序上传至手机PinToo运行；同步时，请确保手机已经运行PinToo，并且已经登陆。

同步中心
PinToo 运行画面

  点击显示日志与开启温湿度订阅按钮，将显示温度与湿度信息。

MQTT控制LED灯
RestAPI控制LED灯

← RestAPI控制LED灯→

Copyright © 2021-2025 爱招飞IsoFace | ALL Rights Reserved